;
;	ＫＢＣ−Ｚ０５サンプルプログラム (1)
;	ＣＴＣの割込みを使い、ＰＩＯに接続した
;	ＬＥＤを点滅させる

;******* Ｉ／Ｏアドレス

CTC0	EQU	10H		;ＣＴＣチャネル0
PIOAD	EQU	1CH		;ＰＩＯ Ａポート データ
PIOAC	EQU	1DH		;ＰＩＯ Ａポート コマンド

;******* ワークエリアと定数

COUNT	EQU	8000H		;割込み回数カウント用エリア
SPEED	EQU	40		;点滅スピード定数

;******* プログラム本体

	ORG	0

	LD	SP,0000H	;スタックポインタ設定
	LD	A,INTTBL/256	;ＣＴＣの割込みテーブル上位を
	LD	I,A		;Ｉレジスタに入れる
	IM	2		;割込みモード２に設定

;******* ＣＴＣの初期化

	LD	A,INTTBL AND 0FFH	;ＣＴＣに割込みベクタを
	OUT	(CTC0),A		;書き込む
	LD	A,10110111B		;ＣＴＣをタイマモードに設定
	OUT	(CTC0),A
	XOR	A			;タイムコンスタント
	OUT	(CTC0),A		;約8.9ミリ秒ごとに割り込む

;******* ＰＩＯ Ａポート初期化（モード３出力）

	LD	A,11001111B	;モード制御語
	OUT	(PIOAC),A
	LD	A,00000000B	;データ入出力制御語（0=出力）
	OUT	(PIOAC),A
	LD	A,00000111B	;割り込み制御語
	OUT	(PIOAC),A

;******* ＰＩＯ Ａポートにデータを出力する

	LD	A,00000001B	;LED が点灯（Ｌレベル）
	OUT	(PIOAD),A
	LD	A,SPEED		;割込み回数カウンタに初期値をセット
	LD	(COUNT),A

	EI			;割込み許可
LOOP:	JR	LOOP		;ＣＴＣの割込みを待つ

;******* 割込み処理ルーチン

INT:	PUSH	AF
	LD	A,(COUNT)	;割込み回数カウンタ
	DEC	A		;0か
	JR	NZ,SKIP		;Ｎｏ，そのままリターン
	IN	A,(PIOAD)	;ＰＩＯ Ａポートを読む
	XOR	00000011B	;ＬＥＤの点滅状態を反転
	OUT	(PIOAD),A	;Ａポートに書き戻す
	LD	A,SPEED		;割込み回数カウンタ再設定
SKIP:	LD	(COUNT),A
	POP	AF
	EI
	RETI

;*******割込みベクタテーブル

	ORG	100H
INTTBL:	DW	INT
	END